Variant
|
||||
| L and R are arbitrary arrays conformable with f, and B is a simple scalar, simple or heterogeneous vector, or nested vector. | ||||
| f is a function. |
Introduction
The dyadic Variant operator creates a version of the function f with a set of properties bound to it as specified by the array right operand. For example, ⍳⍠0 is a version of ⍳ that executes in origin-0 independent of the current value of ⎕IO.
The array right operand to the operator may take several different forms depending upon the function left operand. In the general case, for any kind of function left operand, the right operand may specify a single property in the form of Key Val, or multiple properties in the form of (Key1 Val1) (Key2 Val2) ..., or if the left operand is a primitive function, a shorthand notation may be used as in Val or Val1 Val2.
In the general case, the keys specify a property such as Index Origin as 'IO' or Comparison Tolerance as 'CT', and the value part specifies a value appropriate to the property specified in the matching key. At the moment, the keys that may be used are 'CT', 'DQ', 'DT', 'FPC', 'IO', and 'PP' which stand for the corresponding system variable. Note that for the Variants of L×R and ⌹R there are no corresponding system variables as yet.
For example:
1 2 (3+1e¯9) 3⍳⍠(('IO' 0) ('CT' 1e¯10)) 3
3
1 2 (3+1e¯10) 3⍳⍠(('IO' 0) ('CT' 1e¯10)) 3
2
⍳⍠('IO' 0) 3
0 1 2
⍳⍠('IO' 1) 3
1 2 3
⍳⍠('IO' 0) ⍠('IO' 1) 3
0 1 2
⍳⍠('IO' 1) ⍠('IO' 0) 3
1 2 3
Note that in the last two examples, the lefthand (innermost) value of ⎕IO takes precedence.
If the left operand is a primitive function, the following shorthands may be used:
| Function or Operator |
Right Arg Type |
Meaning |
|---|---|---|
| ⍳R and L⍳R | N | ⎕IO←N |
| N1 N2 | ⎕IO←N1 and ⎕CT←N2 | |
| L⌷R, L⍉R, ⍋R, L⍋R, ⍒R, L⍒R, L⊃R, ⍸R, LπR, a‼R |
N | ⎕IO←N |
| ⍕R and L⍕R | N | ⎕PP←N |
L∊R, L≡R, L≢R, L∪R, L∩R, |
N | ⎕CT←N |
| L|R, f⌻R, L f⌻R, ∘⌻R | N | ⎕CT←N |
| C | ⎕DQ←C | |
| N C | ⎕CT←N and ⎕DQ←C | |
| C N | ⎕CT←N and ⎕DQ←C | |
| ?R and L?R | N | ⎕IO←N |
| C | ⎕DT←C | |
| N C | ⎕IO←N and ⎕DT←C | |
| C N | ⎕IO←N and ⎕DT←C | |
| !R (Pochhammer k-symbol) | N | Rising (N > 0) and Falling (N < 0) factorial of length |N, stepping by 1 in the direction of N |
| N1 N2 | Rising (N1 > 0) and Falling (N1 < 0) factorial of length |N1, stepping by |N2 in the direction of N1 | |
| ⍎R | N | ⎕FPC←N |
| L÷R, L∨R, L∧R, L○R, L⊤R | C | ⎕DQ←C |
| L×R | C | where C may be either 'i' or 'e' for Interior or Exterior product where the former calculates (((L×R)+R×L)÷2 and the latter calculates (((L×R)-R×L)÷2 and L and R are non-commutative (Quaternion or Octonion) numbers — for commutative numbers, both products are trivial. |
| ⌹R | N | where N may be 1, 2, 3, or 4. R must be a square simple Real numeric matrix. If N is 1, the result is a Complex floating point vector of the Eigenvalues of R. If N is 2, the result is a Complex floating point matrix of the Eigenvectors of R, one per column. If N is 3, the result is a two-element nested vector with a Complex vector of the Eigenvalues in the first element and a Complex matrix of the Eigenvectors in the second. If N is 4, the result is a three-element nested vector with a Complex vector of the Eigenvalues in the first element, a Complex matrix of the Eigenvectors in the second, and a Real matrix of the Schur vectors in the third. |
Rising and Falling Factorials
A falling factorial is like a normal factorial except that it subtracts the step value (by default 1 unless overridden) from the original number for a fixed # of iterations. That is, !6 successively decrements 6 by 1 and multiplies the numbers 6 5 4 3 2 1 to get 720. A falling factorial starting with 6 of length (say) 3 multiplies 6 5 4 to get 120.
A rising factorial is like a falling factorial except it adds the step value (by default 1 unless overridden) instead of subtracting it. A rising factorial starting with 6 of length (say) 3 multiplies 6 7 8 to get 336.
Here are some examples of the falling factorial
!6
720
(!⍠¯6)6 ⍝ ×/6 5 4 3 2 1
720
(!⍠¯5)6 ⍝ ×/6 5 4 3 2
720
(!⍠¯4)6 ⍝ ×/6 5 4 3
360
(!⍠¯3)6 ⍝ ×/6 5 4
120
(!⍠¯2)6 ⍝ ×/6 5
30
(!⍠¯1)6 ⍝ ×/6
6
(!⍠¯0)6 ⍝ ×/⍬
1
and now falling by 2
(!⍠¯6 2)6 ⍝ ×/6 4 2 0 ¯2 ¯4
0
(!⍠¯5 2)6 ⍝ ×/6 4 2 0 ¯2
0
(!⍠¯4 2)6 ⍝ ×/6 4 2 0
0
(!⍠¯3 2)6 ⍝ ×/6 4 2
48
(!⍠¯2 2)6 ⍝ ×/6 4
24
(!⍠¯1 2)6 ⍝ ×/6
6
(!⍠¯0 2)6 ⍝ ×/⍬
1
and here are some examples of the rising factorial
(!⍠6)6 ⍝ ×/6 7 8 9 10 11
332640
(!⍠5)6 ⍝ ×/6 7 8 9 10
30240
(!⍠4)6 ⍝ ×/6 7 8 9
3024
(!⍠3)6 ⍝ ×/6 7 8
336
(!⍠2)6 ⍝ ×/6 7
42
(!⍠1)6 ⍝ ×/6
6
(!⍠0)6 ⍝ ×/⍬
1
and now rising by 2
(!⍠6 2)6 ⍝ ×/6 8 10 12 14 16
1290240
(!⍠5 2)6 ⍝ ×/6 8 10 12 14
80640
(!⍠4 2)6 ⍝ ×/6 8 10 12
5760
(!⍠3 2)6 ⍝ ×/6 8 10
480
(!⍠2 2)6 ⍝ ×/6 8
48
(!⍠1 2)6 ⍝ ×/6
6
(!⍠0 2)6 ⍝ ×/⍬
1
Identities
| (!⍠N)R | ←→ | (!⍠(N 1))R | |
| (!⍠(N 0))R | ←→ | R*N | |
| (!⍠(N1,N2))R | ←→ | (!⍠(N1,|N2))R | (the sign of N2 is ignored) |
Eigenvalues and Eigenvectors
These concepts from Linear Algebra and Matrix Theory define the characteristic values and vectors of the linear transformation represented by a matrix. Every square simple Real numeric matrix has Eigenvalues and Eigenvectors. To calculate these objects, use the Variant operator with a left operand of the Domino function and a right operand of an integer scalar according to the following table:
| Z←(⌹⍠1) R | Z is a Complex floating point vector of the Eigenvalues of R |
| Z←(⌹⍠2) R | Z is a Complex floating point matrix of the Eigenvectors of R, one per column |
| Z←(⌹⍠3) R | Z is a two-element nested vector with a Complex floating point vector of the Eigenvalues in the first element and a Complex floating point matrix of the Eigenvectors in the second |
| Z←(⌹⍠4) R | Z is a three-element nested vector with a Complex floating point vector of the Eigenvalues in the first element, a Complex floating point matrix of the Eigenvectors in the second, and a Real matrix of the Schur vectors in the third |
For example, Eigenvalues and Eigenvectors can be used to calculate the factorial of a matrix:
M←2 2⍴1 3 2 1
M
1 3
2 1
MatFact←{(Eval Evec)←(⌹⍠3) ⍵
➥⋄ Diag←∘⌻!Eval ⍝ Factorial of Eigenvalues on diagonal
➥⋄ Evec+.×Diag+.×⌹Evec}
MatFact M
3.6274 8.8423
5.8949 3.6274
Note that if we delete the Shriek function in MatFact, the result is the original matrix argument.
In turn, the function MatFact can be used to calculate the Factorial of a HyperComplex number:
HyperFact←{M←∘⌻⍵ ⍝ Matrix representation of a HyperComplex number
➥⋄ ⎕IO←1 ⋄ <9○1⌷[2] MatFact M ⍝ Factorial ...
➥}
HyperFact 1i2
0.11229J0.32361
!1i2
0.11229J0.32361
where the latter expression uses the Gnu Scientific Library Complex number routines to calculate the Factorial of a Complex number.
In a similar manner, using the appropriate 4×4 matrix representation of a Quaternion, its Factorial can be calculated which is the algorithm used in the implementation:
HyperFact <⍳4
0.0060975i¯0.0010787j¯0.001618k¯0.0021573
!<⍳4
0.0060975i¯0.0010787j¯0.001618k¯0.0021573
| NARS 2000 Lang Tool Bar |
← | → | + | - | × | ÷ | * | ⍟ | ⌹ | ○ | ! | ? | √ | | | ⌈ | ⌊ | ⊥ | ⊤ | ⊣ | ⊢ | |||
| ≡ | ≢ | < | ≤ | = | ≥ | > | ≠ | ∨ | ∧ | ⍱ | ⍲ | ↑ | ↓ | ⊂ | ⊃ | ⌷ | ⍋ | ⍒ | |||||
| ⍳ | ∊ | ⍸ | ⍷ | ∪ | ∩ | ⊆ | ⊇ | ~ | § | π | .. | , | ⍪ | ⍴ | ⌽ | ⊖ | ⍉ | ||||||
| / | \ | ⌿ | ⍀ | ⊙ | ¨ | ⍨ | ⍤ | ⍣ | ⍡ | ⍥ | ⍦ | . | ∘ | ⍠ | ‼ | ⌻ | ∂ | ∫ | ⍞ | ⎕ | ⍎ | ⍕ | |
| ⋄ | ⍝ | ∇ | ∆ | ⍙ | _ | ⍺ | ⍵ | ¯ | ⍬ | ∞ | ∅ | ||||||||||||
| Second Row | i j k | i j k l | g | p | r | v | x | ||||||||||||||||
