Dilate

(diff) ← Older revision | Latest revision (diff) | Newer revision → (diff)
 Z←>R    or    Z←>[X] R extracts from R its Hypercomplex coefficients.
X is an optional numeric singleton axis with X∊⍳1+⍴⍴R. If [X] is omitted, the operation applies to the last axis plus one.
R is an arbitrary Real or Hypercomplex numeric array — otherwise, DOMAIN ERROR.
Z is the corresponding array of Real numbers of shape ((=R),⍴R)[⍋⍋X≠⍳1+⍴⍴R] where =R is the Hypercomplex dimension of R as in (=R)∊1 2 4 8.

For example,

```      ⍴⎕←>23
23
1
⍴⎕←>[1] 23
23
1
⍴⎕←>2 2⍴⍳4
1
2

3
4
2 2 1
⍴⎕←>2 2⍴1J2 3J4 4J3 2J1
1 2
3 4

4 3
2 1
2 2 2
⍴⎕←>[1] 2 2⍴1J2 3J4 4J3 2J1
1 3
4 2

2 4
3 1
2 2 2
⍴⎕←>2 2⍴1i2j3k4 5i6j7k8 8i7j6k5 4i3j2k1
1 2 3 4
5 6 7 8

8 7 6 5
4 3 2 1
2 2 4
⍴⎕←>2 2⍴1i2j3k4l5ij6jk7kl8 9i10j11k12l13ij14jk15kl16 16i15j14k13l12ij11jk10kl9 8i7j6k5l4ij3jk2kl1
1  2  3  4  5  6  7  8
9 10 11 12 13 14 15 16

16 15 14 13 12 11 10  9
8  7  6  5  4  3  2  1
2 2 8
```

Identities

R ←→ < > R   for all R (see Condense for the definition of monadic Left Caret)
R ←→ <[X] >[X] R   for all R
R ←→ > < R   for all R with (¯1↑⍴ R)∊1 2 4 8
1/R ←→ > < R   for all R with (¯1↑⍴1/R)∊1 2 4 8
R ←→ >[X] <[X] R   for all non-scalar R with (⍴R)[X]∊1 2 4 8

Acknowledgements

This symbol and its name were suggested by David A. Rabenhorst.