Train Tables

The following tables list many possible expressions involving one or two arguments and one or more functions, along with their corresponding Train. These entries may be used to construct the Train which corresponds to more complicated expressions. For example, the expression

L e (L f R) g L h R

may be expressed as a Train as follows:

   L e (L f R) g L h R
←→ L e L (f g h) R from the definition of Dyadic Fork
←→ L (⊣ e (f g h)) R from the form for L g L h R

gR:

        g R			g
      R g R			(g ⊢)

Other gR forms using g twice may be obtained from ghR below.

LgR:

           L			(⊣ ⊣)
           R			(⊢ ⊢)
         g R			(⊢ g)
         g L			(⊢ g)⍨
       R g R			(⊢ g ⊢)		(⊢ g⍨)
       R g L			(⊢ g ⊣)		(g ⊢)⍨
       L g L			(⊣ g ⊣)
       L g R			(g ⊢)

Other LgR forms using g twice may be obtained from LghR below.

ghR:

       g h R			((⊢ g) h)
     R g h R			(g h)           Monadic Hook
   g R   h R			((⊢ g) (h ⊢))
  (g R)  h R			(g h ⊢)		(h⍨ g)
 R g R   h R			(g (h ⊢))
(R g R)  h R			((g ⊢) h ⊢)

LghR:

   g     h R			((⊢ g) h)
   g L   h R			(⊢ (⊢ g) h)
  (g L)  h R			(h⍨ g)⍨
 L g     h L			(⊣ g (⊢ h)⍨)
 L g     h R			(g h)          Dyadic Hook
 R g     h R			(⊢ g (⊢ h))
 R g     h L			(g h)⍨
 L g L   h L			(⊣ g ⊣ h ⊣)
 L g L   h R			(⊣ g h)
 L g R   h L			(⊢ g h)⍨
 L g R   h R			(g (h ⊢))
 R g L   h L			(g (h ⊢))⍨
 R g L   h R			(⊢ g h)
 R g R   h L			(⊣ g h)⍨
 R g R   h R			(⊢ g ⊢ h ⊢)
(L g L)  h L			((⊢ g⍨) h ⊢)⍨
(L g L)  h R			(h⍨ (g ⊢))⍨
(L g R)  h L			(g h ⊣)
(L g R)  h R			(g h ⊢)
(R g L)  h L			(g h ⊢)⍨
(R g L)  h R			(g h ⊣)⍨
(R g R)  h L			(h⍨ (g ⊢))
(R g R)  h R			((⊢ g⍨) h ⊢)

fghR:

  (f R) g   h R                (f g h)      Monadic Fork

LfghR:

(L f R) g L h R                (f g h)      Dyadic Fork