Primes

Z←πR returns an integer vector consisting of the prime factors of R.

R is a scalar or one-element vector consisting of a positive integer to be factored.

Z is an integer vector whose values are the prime factors of R.

For example,

      π120
2 2 2 3 5

      ×/⎕←π⎕←¯1+2*62
4611686018427387903
3 715827883 2147483647
4611686018427387903

      π¯1+2*61
2305843009213693951

      ⍴π1
0

Z←LπR returns an integer scalar whose value depends upon which number-theoretic function is chosen by L to be applied to R.

L is an integer scalar whose meaning is as follows 0   Divisor count function 1   Divisor sum function 2   Primality test function 3   Next prime function 4   Previous prime function 5   Nth prime function 6   Number of primes function 7   Möbius function function 8   Euler totient function

R is a scalar consisting of a positive integer to which one of the above functions is applied.

Z is an integer.

Divisor Count Function

The divisor count function (0πR) returns the number of divisors of a number. It is the same as ×/1+∪⍦πR where πR returns the prime factors of R and ∪⍦ counts the number of occurrences of unique elements (in this case, the exponent vector of the unique primes). A divisor then consists of the product of zero or more of the unique primes which is why ×/1+ counts them.

Divisor Sum Function

The divisor sum function (1πR) returns the sum of the divisors of a number. It is the same as ×/(¯1+(∪f)*1+∪⍦f)÷¯1+∪f←πR¹. This function is used to recognize deficient, perfect, and abundant numbers.

Primality Test

The primality test function (2πR) returns a 1 if R is a prime and 0 if not.

Next Prime Function

The next prime function (3πR) returns the prime that immediately follows R.

Previous Prime Function

The previous prime function (4πR) returns the prime that immediately precedes R.

Nth Prime Function

The Nth prime function (5πR) returns the R^th prime where 2 is the first prime.

Number Of Primes Function

The number of primes function (6πR) returns number of primes less than or equal to R.

Möbius Function

The Möbius function (7πR) returns information about the square free properties of R. If R is square free, the function returns 1 if R has an even number of prime factors, and ¯1 if it has an odd number of prime factors. If the argument is not square free, the function returns 0. It is used in the Möbius Inversion Formula to invert general arithmetic functions.

Totient Function

The totient function (8πR) (also called Euler's Totient Function) returns the number of positive integers less than or equal to R that are relatively prime to it (i.e., having no common positive factors other than 1).

Notes

¹ Formula for sum of divisors