Determinant Operator

Z←f.g R returns the generalized determinant of R.

R is a numeric scalar, vector, or matrix.

f and g are functions.

The determinant of a matrix is a value associated with it whose interpretation depends upon the purpose of the matrix. For example, where the matrix represents the coefficients in a system of linear equations, a non-zero determinant indicates that the system has a unique solution, and a zero determinant indicates that the system has either no solutions or many solutions. For the original source document that introduced this operator, see Determinant-Like Functions Produced by the Dot Operator.

There are many formulas that may be used to calculate the value of the determinant, one of which (from Wikipedia, due to Leibniz) is particularly suited to our purposes:

for an n×n matrix, where sgn is the sign function of permutations in the permutation group S_n, which returns +1 and −1 for even and odd permutations, respectively. The latter sum of positive or negative quantities is actually an alternating sum (-/ in APL) and the righthand part is a product of terms (×/ in APL), hence this formula may be described as an alternating sum of products. This means that the usual determinant of a matrix is obtained via -.×. Moreover, the permanent of a matrix uses +.×.

Examples

      ⎕←a←?4 4⍴10
1 8 1 8
5 1 7 2
6 3 9 4
4 9 8 8
      -.×a
26
      +.×a
18886

Alternate Derived Functions

The Leibniz formula nicely allows us to substitute other functions for (-) and (×) to obtain alternate derived functions in order to solve different problems, while still using the same basic algorithm.

One such alternate derived function is ⌊.+ which finds the lowest cost assignment of agents (rows) to tasks (columns) where each agent is assigned one and only one task. For example,

      ⌊.+a
10

This result means that there is a minimal assignment of choices of an entry from each column and each row that sums to 10, a result easily seen using another pair of operands to the Determinant Operator so as to display the actual choices:

      {(+/⍺)<+/⍵:⍺ ⋄ ⍵}.,a
4 3 1 2

That is, a minimal set of choices is the 4 in column 1, the 3 in column 2, the 1 in column 3, and the 2 in column 4, which, by construction, are all in different rows.

Moreover, just as -.× uses an optimized algorithm (LU Decomposition), so does ⌊.+ (Kuhn's Hungarian Algorithm) as well as ⌈.+ and {(+/⍺)<+/⍵:⍺ ⋄ ⍵}, along with a number of variations of the latter anonymous function (e.g. {(+/⍺)>+/⍵:⍺ ⋄ ⍵}, {(+/⍺)<+/⍵:⍵ ⋄ ⍺}, etc.). Consequently, all of the above derived functions return results very quickly for reasonably large arguments. For example, ⌊.+ on a random 50 by 50 matrix takes only a few milliseconds.

Another variant of the lowest cost assignment is ⌊.× and ⌈.×. Rather than treat these expressions specially, they can be resolved via the identities ⌊.×R ←→ *⌊.+⍟R and ⌈.×R ←→ *⌈.+⍟R.

References

1. Determinant-Like Functions Produced by the Dot Operator, SATN-42 (Sharp APL Technical Notes), 1982-04-01, by K.E. Iverson
2. Leibniz Formula, from Wikipedia
3. Permanent, from Wikipedia
4. Assignment Problem, from Wikipedia