Difference between revisions of "System Function DR"
Sudleyplace (talk  contribs) 
Sudleyplace (talk  contribs) 

Line 178:  Line 178:  
===A Word of Caution===  ===A Word of Caution===  
−  <p>This system function allows you to create special numbers we don't  +  <p>This system function allows you to create special numbers we don't support in that no other primitive generates these numbers and the behavior of all other primitives on these numbers is undefined. Examples of such special numbers include '''Quiet NaNs''', '''Signaling NaNs''', '''Negative Zero''', and '''Denormals'''. If the system doesn't behave as you expect when using these special numbers, don't be surprised.</p> 
<p>For example,</p>  <p>For example,</p> 
Revision as of 15:57, 9 October 2008
Monadic Function


R is an arbitrary array.  
Z is a numeric scalar which represents the datatype of R. 
The datatypes are encoded with a unique index in the loworder two digits, and the bits per element in the remaining digits:
 100: Boolean, one bit per element
 1601: Character, 16 bits per element
 6402: Integer, 64 bits per element
 6403: Floating Point, 64 bits per element (double precision)
 6404: Arithmetic Progression Array, 64 bits each for the offset and multiplier
 3208: Heterogeneous, 32 bits per element (each is a pointer)
 3209: Nested, 32 bits per element (each is a pointer)
For example,
⎕DR 1 0 1
100
⎕dr ⌈/⍬
6403
⎕dr 2 64⍴1 — Note this is really an APA, not Boolean
6404
⎕dr 2 64⍴1 1 — This one is Boolean because Reshape produces APAs for integer singleton right arguments only
100
Dyadic Function


R is an arbitrary array.  
L is an integer scalar or oneelement vector datatype (see the table above), or a special value (see below).  
Z is R where each of the values are converted to the datatype indicated by L. 
If the conversion is from a narrower datatype to a wider datatype, there must be exactly enough columns in the right argument to match a multiple of the size of the wider datatype. For example, when converting from character (16bit) to integer (64bit), the last column of the right argument must be a multiple of 4 (= 64/16); otherwise, a LENGTH ERROR is signalled.
6402 ⎕dr 'NARS2000' — Eight 16bit characters (=128 bits) convert to two 64bit integers
23362775258562638 13511005043687474
If the conversion is from a wider datatype to a narrower datatype, the number of values in the result is a multiple of the ratio of the wider datatype to the narrower datatype. For example, when converting from integer (64bit) to character (16bit), the last column in the result is the product of last column of the right argument and 4 (= 64/16).
For example,
⍴⎕←1601 ⎕dr 23362775258562638 13511005043687474
NARS2000
8
Keep in mind how Arithmetic Progression Arrays are created and represented as they can fool you. For example, you might try the following to convert from Boolean to integer:
6402 ⎕dr 2 64⍴1
1 0 2 64
However, this doesn't produce the expected result because this particular right argument is an APA, not a Boolean vector. That is, under certain circumstances, the reshape primitive creates an APA. In this case, the APA is an array with an offset of 1, a multiplier of 0 and a shape of 2 64.
On the other hand, this expression
6402 ⎕dr 2 64⍴1 1
¯1
¯1
produces the expected result because the right argument is now Boolean.
Special Values
There are several special values you may use as a left argument to ⎕dr:
The value 0 displays the datatype of the right argument as a text string so you don't need to remember the datatype numbers.
For example,
⎕dr 'a'
1601
0 ⎕dr 'a'
Character (1601): 16 bits per element
0 ⎕dr ⍳12
Arithmetic Progression Array (6404): 64 bit offset + 64 bit multiplier
The value 1 converts between character and floating point. This argument makes it easy to see the representation of floating point numbers in order to help understand precision and other floating point issues.
For example,
1 ⎕pp←99
1 ⎕dr 1.1
3FF199999999999A
1 ⎕dr '3fd',13⍴'5'
0.33333333333333331
1 ⎕dr ¯∞ ∞
FFF0000000000000
7FF0000000000000
1 ⎕dr '7fe',13⍴'f' — The largest positive number
1.7976931348623157E308
1 ⎕dr '001',13⍴'0' — The smallest positive number
2.2250738585072014E¯308
1 ⎕dr '801',13⍴'0' — The largest negative number
¯2.2250738585072014E¯308
1 ⎕dr 'ffe',13⍴'f' — The smallest negative number
¯1.7976931348623157E308
The value 2 converts between character and 64bit integer. This argument makes it easy to see the representation of integers.
For example,
2 ⎕dr ¯1
FFFFFFFFFFFFFFFF
2 ⎕dr '7',15⍴'f' — The largest positive integer
9223372036854775807
2 ⎕dr '8',15⍴'0' — The smallest negative integer
¯9223372036854775808
2 ⎕dr 9223372036854775807 ¯9223372036854775808
7FFFFFFFFFFFFFFF
8000000000000000
A Word of Caution
This system function allows you to create special numbers we don't support in that no other primitive generates these numbers and the behavior of all other primitives on these numbers is undefined. Examples of such special numbers include Quiet NaNs, Signaling NaNs, Negative Zero, and Denormals. If the system doesn't behave as you expect when using these special numbers, don't be surprised.
For example,
⎕ct←0 ⋄ ⎕pp←99
6403 ⎕dr ¯64↑1
¯0
QNaN←6403 ⎕dr ¯64↑13⍴1 — A Quiet NaN (Not a Number)
1 ⎕dr QNaN
FFF8000000000000
QNaN=1 2 3 ∞
1 1 1 1
1 ⎕dr '000fffffffffffff' — The largest positive denormal
2.2250738585072009E¯308
1 ⎕dr '0000000000000001' — The smallest positive denormal
4.9406564584124654E¯324