Condense

From NARS2000
Revision as of 22:50, 9 April 2017 by WikiSysop (talk | contribs)
Jump to navigationJump to search
The printable version is no longer supported and may have rendering errors. Please update your browser bookmarks and please use the default browser print function instead.
Z←<R converts R to a Hypercomplex array if (≢R)∊2 4 8 or a Real array if 1=≢R.
R is an arbitrary Real numeric array (BOOL, INT, FLT, APA, RAT, VFP — otherwise, DOMAIN ERROR) whose number of columns (≢R) is 1, 2, 4, or 8 — otherwise, LENGTH ERROR.
Z is the corresponding Real or Hypercomplex array of shape ¯1↓⍴R using the columns of R as the coefficients of the resulting Real or Hypercomplex array. If ≢R is 1, the result is the Real array (¯1↓⍴R)⍴R, if ≢R is 2, the result is a Complex array, if ≢R is 4, the result is a Quaternion array, and if ≢R is 8, the result is an Octonion array.


For example,

      <23
23
      <10 20
10J20
      <2 4⍴⍳8
1i2j3k4 5i6j7k8
      <2 8⍴(⍳8),⌽⍳8
1i2j3k4l5ij6jk7kl8 8i7j6k5l4ij3jk2kl1
      ⍴⎕←<2 3 1⍴⍳6
1 2 3
4 5 6
2 3
      ⍴⎕←<2 3 2⍴(⍳6),⌽⍳6
1J2 3J4 5J6
6J5 4J3 2J1
2 3
      ⍴⎕←<2 3 4⍴(⍳12),⌽⍳12
1i2j3k4    5i6j7k8 9i10j11k12
12i11j10k9 8i7j6k5 4i3j2k1
2 3
      ⍴⎕←<2 3 8⍴(⍳24),⌽⍳24
 1i2j3k4l5ij6jk7kl8         9i10j11k12l13ij14jk15kl16 17i18j19k20l21ij22jk23kl24
24i23j22k21l20ij19jk18kl17 16i15j14k13l12ij11jk10kl9   8i7j6k5l4ij3jk2kl1
2 3

Identities

R ←→ <>R   for all R (see Dilate for the definition of monadic Right Caret)
R ←→ ><R   for all R with (¯1↑⍴R)∊1 2 4 8

Acknowledgements

This symbol and its name were suggested by David A. Rabenhorst.