Anonymous Functions/Operators/Hyperators

From NARS2000
Jump to: navigation, search

Anonymous functions, operators, and hyperators (AFOHs) are a one- or multi-line grouping of one or more statements all enclosed in braces such as {(+⌿⍵)÷≢⍵}. This syntax is useful for one- or multi-line functions, operators, and hyperators to complement the existing definition types of user-defined: ∇ Z←avg R, trains: (+⌿ ÷ ≢), and derived: ,∘⍋∘⍋∘,.

These objects may be named as in avg←{(+⌿⍵)÷≢⍵}, and named or unnamed may be used in place of any APL function (primitive, operator operand, hyperator hyperand, derived, train, user-defined) including within another AFOH.

Contents

Function Arguments

To define an anonymous function, use as the name of the (optional) left argument, as the name of the (optional) anonymous function (for recursion only), and as the name of the right argument. For example,

      3 5{√+/⍺ ⍵*2}4 12           ⍝ Pythagorean theorem
5 13
      {s←(+/⍵)÷2 ⋄ √×/s-0,⍵}3 4 5 ⍝ Heron's formula for triangle area
6

Operator Operands

To define an anonymous operator, use the above special names along with ⍺⍺ as the name of the left operand, ∇∇ as the name of the (optional) operator (for recursion only), and ⍵⍵ as the name of the (optional) right operand. If neither ⍺⍺ nor ⍵⍵ appears as a token between the braces and outside of character constants, then the object is a function, not an operator. For example,

opr←{∘.⍺⍺⍨⍳⍵}

=opr 4 1 0 0 0 0 1 0 0 0 0 1 0 0 0 0 1

⌈opr 4 1 2 3 4 2 2 3 4 3 3 3 4 4 4 4 4

*opr 4 1 1 1 1 2 4 8 16 3 9 27 81 4 16 64 256

≤opr 4 1 1 1 1 0 1 1 1 0 0 1 1 0 0 0 1

In the above examples, the functions = ⌈ * ≤ are the Left Operands to the Operator opr.

Hyperator Hyperands

To define an anonymous hyperator, use the above special names along with ⍺⍺⍺ as the name of the left hyperand, ∇∇∇ as the name of the (optional) hyperator (for recursion only), and ⍵⍵⍵ as the name of the (optional) right hyperand. If neither ⍺⍺⍺ nor ⍵⍵⍵ appears as a token between the braces and outside of character constants, then the object is a function or operator, not a hyperator. For example,

hyp←{⍺⍺ ⍺⍺⍺⍨⍳⍵}

=∘.hyp 4 1 0 0 0 0 1 0 0 0 0 1 0 0 0 0 1

⌈∘.hyp 4 1 2 3 4 2 2 3 4 3 3 3 4 4 4 4 4

*∘.hyp 4 1 1 1 1 2 4 8 16 3 9 27 81 4 16 64 256

≤∘.hyp 4 1 1 1 1 0 1 1 1 0 0 1 1 0 0 0 1

In the above examples, the Monadic Operator ∘. is the Left Hyperand and the functions = ⌈ * ≤ are the Left Operands to the Hyperator hyp.

Ambivalent AFOHs

User-defined functions/operators/hyperators allow you to specify in their headers that the left argument is optional by enclosing it in braces, as in ∇ Z←{L} foo R, and to test for the presence or absence of the optional argument using 0=⎕NC 'L'.

This behavior is also available to AFOHs by including a statement that assigns a value to . If does not have a value when that statement is encountered, the statement is executed; otherwise, that entire statement is ignored including any side effects. This behavior obviates the need to use 0=⎕NC '⍺' to test for a value in . It also means that as a consequence of this rule, regardless of how the AFOH is called, any second or subsequent statements that assign a value to are always ignored.

For example,

      f←{⍺←2 ⋄ ⍺√⍵}
      f 16
4
      3 f 27
3
      f←{⎕←⍺←⍵ ⋄ (⍳⍺)∘.⍺⍺⍳⍵}
      ⌊f 4
4
1 1 1 1
1 2 2 2
1 2 3 3
1 2 3 4
      3⌊f 4
1 1 1 1
1 2 2 2
1 2 3 3
      f←{⎕←⍺←9 ⋄ ⎕←⍺←0 ⋄ ⍺+⍵}
      4 f 12 ⍝ Both assignments of ⍺ ignored
16
      f 12   ⍝ Second assignment of ⍺ ignored
9
21

Valences

An AFOH may be

  • Ambivalent (must be called with either one or two arguments),
  • Dyadic (must be called with two arguments),
  • Monadic (must be called with one argument), or
  • Niladic (must be called with no arguments),

depending upon which of the special symbols are present in its definition.

Disregarding special symbols inside of character constants and/or comments

  • For anonymous functions (and operators/hyperators):
    • If ⍺← appears as a sequence of tokens, then the (derived) function is ambivalent,
    • Otherwise, if appears as a token, the (derived) function is dyadic,
    • Otherwise, if appears as a token, the (derived) function is monadic,
    • Otherwise, if neither nor appears as a token, the (derived) function is niladic.
  • For anonymous operators only:
    • If ⍵⍵ appears as a token, the operator is dyadic (must be called with two operands — left and right),
    • Otherwise, if ⍺⍺ appears as a token, the operator is monadic (must be called with one operand — left only).
  • For anonymous hyperators only:
    • If ⍵⍵⍵ appears as a token, the hyperator is dyadic (must be called with two hyperands — left and right),
    • Otherwise, if ⍺⍺⍺ appears as a token, the hyperator is monadic (must be called with one hyperand — left only).

For example,

      {⍵}2
2
      1{⍵}2
VALENCE ERROR
      1{⍵}2
       ^
      1{⍺+⍵}2
3
      {⍺+⍵}2
VALENCE ERROR
      {⍺+⍵}2
      ∧
      {⍺←2 ⋄ ⍺+⍵}2  ⍝ Ambivalent function, monadic with default left argument 2
4
      3{⍺←2 ⋄ ⍺+⍵}2 ⍝ Ambivalent function, dyadic with left argument 3
5
      {⍳3}          ⍝ A three-element simple vector
1 2 3
      {⍳3}23        ⍝ A two-element nested vector
 1 2 3  23
      12{⍳3}23      ⍝ A three-element nested vector
 12  1 2 3  23
      3{∘.=⍨⍳⍺⍺}    ⍝ A niladic derived function from a monadic operator
1 0 0
0 1 0
0 0 1

Multi-Line AFOHs

An AFOH may be defined on multiple lines (just like User-Defined Functions/Operators/Hyperators) by first naming it (e.g. h←{s←(+/⍵)÷2 ⋄ √×/s-0,⍵}), and then editing it in the usual way (e.g., ∇h). For more details, see Function Editing.

Guards

Guards are used to test for a condition and execute a statement or not depending upon the value of the conditional expression. This behavior is identical to the control structure

:if Cond ⋄ CondStmt ⋄ :return ⋄ :end

Guards appear as a Boolean-valued APL expression (Cond) followed by a colon, followed by a single APL statement (CondStmt) as in

{... ⋄ Cond:CondStmt ⋄ ...}

which executes CondStmt and terminates the AFOH if and only if Cond evaluates to TRUE (1).

For example,

{... ⋄ 0∊⍴⍵:'empty right argument' ⋄ ...}

As many guard statements may appear in an AFOH as desired. They are executed in turn until one of them evaluates to TRUE, at which time the statement following the colon is executed and the function terminates with any result of that conditional statement as the result of the AFOH.

If Cond does not evaluate to a Boolean-valued scalar or one-element vector, a RANK, LENGTH, or DOMAIN ERROR is signalled, as appropriate.

If the rightmost statement is executed and it is a guard statement whose Cond evaluates to FALSE (0), the AFOH terminates with no value; if the result of that AFOH is assigned, a VALUE ERROR is signalled.

Chaining Guards

If the Cond in a Guard statement evaluates to TRUE, the next statement may be another Guard statement, and so forth, each of which further reduces the likelihood of evaluating CondStmt. For example,

{Cond1: Cond2: Cond3: ... CondStmt ⋄ ...}

The effect of chaining several Guard statements together is to evaluate each Cond from Left-to-Right, and as soon as one of the Conds evaluates to FALSE, evaluation of the remainder of Conds stops and the CondStmt is skipped. Only if all Conds are TRUE is CondStmt executed.

Outside of Anonymous Functions, this syntax is equivalent to joining the Conds with :andifs as in

:if Cond1 ⋄ :andif Cond2 ⋄ :andif Cond3 ⋄ ... ⋄ CondStmt ⋄ :return ⋄ :end

Compare this with

:if Cond1 ∧ Cond2 ∧ Cond3 ... ⋄ CondStmt ⋄ :return ⋄ :end

which has the (undesired) effect evaluating all of the Conds (from Right-to-Left!) even if an early Cond evaluates to FALSE.

For example, to test for a Simple Positive Even Scalar Number,

      f←{0=≡⍵: 0 0≡⊤0,⍵: 0<⍵: 0=2|⍵: 'Oui' ⋄ 'Non'}
      f¨12 ¯12 (,12) 33 34 'A' 1r1 2r1 0r1 0v 1.1v 2v
 Oui Non Non Non Oui Non Non Oui Non Non Non Oui

Shy Results

A "shy" result is any result that doesn't automatically display its value, a simple example of which is L←⍳3: the result is ⍳3 (as evidenced by the extension to 3+L←⍳3), but because it has been assigned to a name, the result doesn't automatically display. Other ways to produce a shy result are to use the Sink syntax ←⍳3, or to call a user-defined function that declares in its header that the result is shy as in ∇ {Z}←foo R.

A shy result propagates up the chain of results just as it does through the Execute primitive. That is, if the last statement executed has a shy result, the result of Execute is shy, too.

Typically, ⎕← is used to expose a shy result.

AFOHs also may have shy results by virtue of the final result being

  • Sinked,
  • Assigned to a name, or
  • From a shy user-defined function.

For example,

      {←⍳3}
      ⎕←{←⍳3}
1 2 3
      {L←⍳3}
      ⎕←{L←⍳3}
1 2 3

Ordinarily, a shy result doesn't terminate the AFOH, as in

      {←⍳3 ⋄ 'abc'}
abc

To force termination, precede the assignment with a guard as in

{⍵=0:←'Zero' ⋄ ⍵>0:←'Positive' ⋄ ←'Negative'} R

which terminates with a shy result in all three cases.

Localization

Unlike user-defined functions, in AFOHs all names to which an assignment is made are automatically localized. As a result, a direct assignment inside an AFOH cannot affect the value of a name defined higher up in the execution chain unless it is made via a user-defined function or the Execute primitive as in

      L←⍳9 ⋄ {L←"abc" ⋄ ⍵}23
23
      L
1 2 3 4 5 6 7 8 9
      L←⍳9 ⋄ {⍎'L←"abc"' ⋄ ⍵}23
23
      L
abc

Scoping

When calls to user-defined functions are nested, a reference to a name by an inner function is resolved by looking up the chain of nested functions for the nearest level at which that name is localized. Looked at from a different perspective, when a name is localized to a function, its scope consists of all functions called by that function. This is called dynamic scoping.

AFOHs use a different mechanism where names referenced by an AFOH are resolved by the context in which the AFOH is defined, not where it is used. This is called lexical scoping or static scoping.

In other words, to paraphrase Wikipedia, "This means that if function f invokes function g that is defined outside the context of f, then under lexical scoping, function g does not have access to f's local variables (since the definition of g is not inside the definition of f), while under dynamic scoping, function g does have access to f's local variables (since the invocation of g is inside the invocation of f)".

For example,

    ∇ foo;f g a
[1]   a←'static'
[2]   ←⎕fx 'f R;a' 'a←"dynamic"' 'g R'
[3]   ←⎕fx 'g R' '"scope ←→ ",a'
[4]   f 'a'
    ∇

      foo
scope ←→ dynamic
      {a←'static' ⋄ f←{a←'dynamic' ⋄ g ⍵} ⋄ g←{'scope ←→ ',a ⋄ ⍵} ⋄ f 'a'}
scope ←→ static

Recursion

AFOHs may be called recursively, but because they might be unnamed (i.e., anonymous), the symbol is used to name the AFOH.

For example, with anonymous functions,

      ⍝ Fibonacci sequence algorithm
      f←{⍺←10 ⋄ ⍺=1:⍵ ⋄ (⍺-1)∇⍵,+/¯2↑⍵}
      f 1
1 1 2 3 5 8 13 21 34 55
      20 f 1
1 1 2 3 5 8 13 21 34 55 89 144 233 377 610 987 1597 2584 4181 6765
      ⍝ Euclidean algorithm for Greatest Common Divisor
      12 {⍺=0:|⍵ ⋄ (⍵|⍺)∇⍺} 8
4

With anonymous operators,

* references the operator with its operand(s) already bound (that is, references the entire derived function)
* ∇∇ references the operator with its operand(s) not bound (that is, ∇∇ references the operator itself)

That is,

* for monadic anonymous operators ∇ ←→ ⍺⍺∇∇
* for dyadic anonymous operators ∇ ←→ ⍺⍺∇∇⍵⍵

With anonymous hyperators,

* references the hyperator with both its hyperand(s) and operand(s) already bound (that is, references the entire derived function)
* ∇∇ references the hyperator with just its hyperand(s) bound (that is, ∇∇ references the operator part of the hyperator)
* ∇∇∇ references the hyperator with neither its hyperand(s) nor operand(s) bound (that is, ∇∇∇ references the hyperator itself)

That is,

* for anonymous monadic hyperand monadic operand hyperators,     ∇ ←→ ⍺⍺∇∇ ←→ ⍺⍺ ⍺⍺⍺∇∇∇
* for anonymous monadic hyperand dyadic operand hyperators,     ∇ ←→ ⍺⍺∇∇⍵⍵ ←→ ⍺⍺ ⍺⍺⍺∇∇∇⍵⍵
* for anonymous dyadic hyperand monadic operand hyperators,     ∇ ←→ ⍺⍺∇∇ ←→ ⍺⍺ ⍺⍺⍺∇∇∇⍵⍵⍵
* for anonymous dyadic hyperand dyadic operand hyperators,     ∇ ←→ ⍺⍺∇∇⍵⍵ ←→ ⍺⍺ ⍺⍺⍺∇∇∇⍵⍵⍵ ⍵⍵

For example, with anonymous operators,

      ⍝ Generalized definition of vector reduction
      f←{0=⍴⍵:⍺⍺/0⍴⍵ ⋄ 1=⍴⍵:⊂↑⍵ ⋄ ⊂(↑⍵)⍺⍺ ⊃∇1↓⍵}
      +f⍳4
10
      ×f⍳4
24
      +f(1 2)(3 4)
 4 6

A more advanced example of recursion of an anonymous operator is hyperoperation expressed below as a monadic operator where its operand N indexes successively more powerful functions as derived functions:

  • N=0 is the successor function (i.e., adds 1 to ),
  • N=1 is the addition function of to , i.e. the successor function on repeated times — ⍺+⍵,
  • N=2 is the multiplication function of by , i.e. the addition function on repeated times — +/⍵⍴a ←→ ⍺×⍵,
  • N=3 is the exponentiation function of to the power , i.e. the multiplication function on repeated times — ×/⍵⍴a ←→ ⍺*⍵,
  • N=4 is the tetration function (related to the Ackermann-Péter function), i.e. the exponentiation function on repeated times — */⍵⍴⍺,
  • N=5 is the pentation function, i.e. the tetration function on repeated times,
  • etc.

written on multiple lines using Line Continuations for clarity:

  ho←{⍺⍺=0     :⍵+1
 ⋄ (⍺⍺=1)∧⍵=0:⍺
 ⋄ (⍺⍺=2)∧⍵=0:0
 ⋄ (⍺⍺≥3)∧⍵=0:1
 ⋄ ⍺ ((⍺⍺-1)∇∇) ⍺∇⍵-1}

      2 (0 ho) 5 ⍝ Successor:  1+5 (left argument ignored)
6
      2 (1 ho) 5 ⍝ Addition:  2+5
7
      2 (2 ho) 5 ⍝ Multiplication:  2×5
10
      2 (3 ho) 5 ⍝ Exponentiation:  2*5
32
      2 (4 ho) 5 ⍝ Tetration:  */5⍴2
200352993040684646497907235156025575044782547556975141926501697371089405955...

Computing */5⍴2x takes but a fraction of a second and returns a number with 19,729 digits!

N.B.: All of the , ∇∇, and ∇∇∇ names may be used in user-defined recursive functions/operators/hyperators, where they have the same meaning as they do in AFOHs.

Termination

Normally, the statements within the braces execute one by one from left to right, just as in the Execute primitive. Execution of the AFOH terminates on the first occurrence of one of the following:

  • A Guard with a TRUE condition,
  • A non-Shy value to display, or
  • The rightmost statement.

Restrictions

  • Assignments to any of the special names (, , ⍺⍺, ∇∇, ⍵⍵, ⍺⍺⍺, ∇∇∇, ⍵⍵⍵) except for are not allowed; they signal a SYNTAX ERROR.
  • Assignments to within a guard statement are not allowed; they signal a SYNTAX ERROR.
  • None of the special names may be erased, via ⎕EX or otherwise.
  • Goto statements are not allowed; they signal a SYNTAX ERROR.
  • Control structures (e.g., :if ... ⋄ ... ⋄ :end) are not allowed; they signal a SYNTAX ERROR.
  • Line labels except for System Labels are not allowed.

Acknowledgements

This design of this feature was copied (with minor changes) from the same feature designed and implemented by John Scholes and other folks at Dyalog, Inc.